version 11.0
set more on
log using 11.2.Isoproterenol.log, replace
*  11.2.Isoproterenol.log
*
*  Plot mean forearm blood flow by race and log dose of isoproternol 
*  using the data of Lang et al. (1995).  Show standard deviation for 
*  each race at each drug level.
*
use C:\wddtext\11.2.Isoproterenol.dta, clear
table race, row
list if id==1 | id ==22
generate baseline = fbf0
*
* Convert data from one record per patient to one record per observation.
*
more
reshape long fbf, i(id) j(dose)
list if id==1 | id ==22
generate delta_fbf = fbf-baseline
label variable delta_fbf "Change in Forearm Blood Flow"
label variable dose "Isoproterenol Dose (ng/min)"
generate plotdose = dose
replace plotdose=6    if dose == 0
label variable plotdose "Isoproterenol Dose (ng/min)"
generate logdose = log(dose)
label variable logdose "Log Isoproterenol Dose"
*
*  Save long format of data for subsequent analyses
*
save C:\wddtext\11.2.Long.Isoproterenol.dta, replace
*
*  Generate Figure 11.1
*
more
collapse (mean) fbfbar=fbf (sd) sd=fbf, by(race plotdose)
generate blackfbf = .
generate whitefbf = .
generate whitesd = .
generate blacksd = .
replace whitefbf = fbfbar if race==1
replace blackfbf = fbfbar if race==2
replace blacksd = sd if race==2
replace whitesd = sd if race==1
label variable whitefbf "Forearm Blood Flow (ml/min/dl)"
label variable blackfbf "Forearm Blood Flow (ml/min/dl)"
generate wsdbar = whitefbf-whitesd
generate bsdbar = blackfbf-blacksd
replace wsdbar = whitefbf+ whitesd if plotdose < 20
more
twoway connected whitefbf plotdose, color(red)  	///
    || rcap whitefbf wsdbar plotdose, color(red)  	///
    || connected blackfbf plotdose, color(blue)    	///
    || rcap blackfbf bsdbar plotdose, color(blue)	///
    ||, ytitle(Forearm Blood Flow (ml/min/dl)) 				 ///
        legend(ring(0) position(11) col(1) order(1 "Whites" 3 "Blacks")) ///
        xtitle(Isoproterenol Dose (ng/min)) xscale(log) 		 ///
        xlabel(6 "0" 10 20 30 60 100 150 200 300 400, angle(45)) 	 ///
        xmtick(40(10)90 250 350) 
more
*
*	Plot individual responses for white and black patients
*
use C:\wddtext\11.2.Long.Isoproterenol.dta, clear
sort id plotdose
twoway connected fbf plotdose, connect(L)  xscale(log) 				///
    xlabel(6 "0" 10 20 30 60 100 150 200 300 400, angle(45)) 		///
    xmtick(40(10)90 250 350) ylabel(0(5)40, angle(0)) 			///
    ytitle(Forearm Blood Flow (ml/min/dl)) by(race)
log close