Using Sage for math

Download/installation

• If all you want to do is use the web-based notebook, but you do have internet access, you don't have to download anything. Just go to http://www.sagenb.org.
• If you want to use Sage in other ways, download from http://www.sagemath.org/download.html (very large file).
• The Sage website has detailed download/installation directions. In addition, you will probably need to add the path to Sage to your $PATH environment variable after installation.

Ways to use Sage

• The web-based notebook (see above)
• If you have downloaded Sage, you have several options:
  • The interactive shell (type quit or exit when you're done). Useful commands: who, reset(), restore(). Also: tab-autocompletion.
  • The notebook (if you start the notebook from the interactive shell, type Ctrl-c in the shell after you sign out of the notebook)
  • Save a .sage file (say, "myfile.sage") and then either
    • type sage myfile.sage in a terminal window, or
    • type load('myfile.sage') or attach('myfile.sage') the file in the Sage interactive shell. Useful commands: attached_files(), detach()
  • Through Python, by importing Sage as a library

A few basic examples

var('x')
f(x) = e^x * cos(x)
f.integrate(x)
f.integrate(x, 0, 5)
f.integrate(x, 0, 5).n()

var('x y')
f(x) = (x^2 - 1) / (x^4 + 1) * y
f.derivative(x)
f.derivative(y)
f.derivative(y, 2)
f.derivative(y, x)

var('x y')
# simplifying
f(x) = sqrt(x^2 + x) / sqrt(x)
f.simplify_radical()

# expanding
expr1 = (x + 3)^3 == (x - 1)^2
expr1.expand()
expr1.lhs().expand()

# factoring
g(x) = x^2 - 1
g.factor()

var('x y')
solns = solve([x^2 + y^2 == 1, y^2 == x^3 + x + 1], x, y, solution_dict= True)
for soln in solns:
    print("x= {0}, y = {1}".format(soln[x], soln[y]))

g(x) = expand((x^2 - 1)^3 * (x^2 + 1) * (x - 2))
print(g)
root_list = g.roots(x)
for root in root_list:
    print("Root: {0} (multiplicity: {1})".format(root[0], root[1]))
p1 = plot(g, (-2, 2))
p1.ymin(-10)
p1.show()

var('x')
f(x) = 1/x
limit(f, x = 0, dir= '+')
limit(f, x = 0, dir= '-')
limit(f, x= 0)   # Does this seem right? Note absence of sign
limit(f, x= oo)
p1 = plot(f, (x, -1, 1), detect_poles= 'show')
p1.axes_range(-1, 1, -10, 10)
p1.show()

var('x, k')
colors= ['red', 'black', 'blue', 'magenta']

x1 = pi/2
xmin = x1 - pi
xmax = x1 + pi

f(x) = sin(x)
p1 = plot(f, (xmin, xmax), color= colors[0], legend_label= 'sin(x)')

Taylor_ser_1(x) = f.taylor(x, x1, 1)
p1 += plot(Taylor_ser_1, (xmin, xmax), legend_label= '1', color= colors[1])

Taylor_ser_3(x) = f.taylor(x, x1, 3)
p1 += plot(Taylor_ser_3, (xmin, xmax), legend_label= '3', color= colors[2])

Taylor_ser_5(x) = f.taylor(x, x1, 5)
p1 += plot(Taylor_ser_5, (xmin, xmax), legend_label= '5', color= colors[3])

Taylor_ser_5
show(p1)

rationalVector1 = vector(QQ, [1, 2/7, 10/3])
rationalVector1
realVector1 = vector(RR, [1, 2/7, 10/3])
realVector1
var('a, b, c')
symbolicVector1 = vector(SR, [a, b, c])
symbolicVector1

rationalVector1.dot_product(symbolicVector1)
rationalVector1.pairwise_product(symbolicVector1)

var('d e f')
ratMatrix = matrix(QQ, [[4, 2, 1], [5, 3, 7]])
symbMatrix = matrix(SR, [[a, b], [c, d], [e, f]])
ratMatrix * symbMatrix

symbolicVector1 * symbMatrix
ratMatrix * symbolicVector1      
restore('e') 

A = matrix(QQ, [[2, 5, 4], [3, 1, 2], [5, 4, 6]])  # examples look nicer with QQ; for real numbers, use RR instead
A.det()
A.rank()
A.transpose()
A.inverse()

b= vector(QQ, [1,2,3])
A.solve_right(b)      # get the solution to A.x = b

R users, watch out!

• Sage uses zero-based indexing. That is, if myVector is equal to (10, 20, 30, 40, 50), then myVector[1] is equal to 20, not 10.
• If Sage's indexing were otherwise like R's indexing, then in the above example, myVector[0:2] would give you (10, 20, 30). But it doesn't. In Sage, a 'slice' starts with the first element in the specified range and continues up to, but not including, the last element in the named range. So myVector[0:2] gives you (10, 20).
• The minus sign in an index means different things in R and Sage. In the above example, myVector[-1] is equal to 50.
• In Sage, matrices are defined by row, not by column.
• The only assignment operator in Sage is the single equals sign, =. R's symbol <- will not work.
• In Sage, exp(2) equals e^2. To get the result you would get in R (a numerical approximation), use exp(2).n() or exp(2).n(digits = 5), etc.
• 10/3 in Sage equals 10/3. To get the result you would get in R, use 10.0/3, or 10/3.0, etc.

Python users, watch out!

• ^ in Sage is equivalent to Python's **. (Sage also recognizes **; you can use either one to raise something to a power.) If you want XOR in Sage, see http://www.sagemath.org/doc/faq/faq-usage.html.
• 10/3 in Sage equals 10/3. To get an integer quotient, use 10//3.

Sage and LaTeX

• If you just want to cut and paste (see http://www.sagemath.org/doc/tutorial/latex.html for more information):

var('x x0 theta')
var('yhat', latex_name= "$\hat{y}$")
f(x) = (x + x0)^theta / (2*yhat)
latex(f(x))

• Calling Sage from within a .tex or .Rnw file
  • If you are using Mac OS X version 10.7.5, you might need to update X11 first: http://support.apple.com/kb/DL1605
  • See http://www.sagemath.org/doc/tutorial/sagetex.html to get started; full documentation is included in the download

Learning more/getting help

• Tutorials, documentation, FAQ: http://www.sagemath.org/help.html
• Sage Q & A community: http://ask.sagemath.org
• Sage Q & A on Stack Overflow: http://stackoverflow.com/questions/tagged/sage
• A very helpful book. The Vanderbilt library has a free electronic copy.